FORUM DU LOGICIEL PRISM

Code : Tout sélectionner

GetVersionScript Version
if Version<1.85
 print "Ce script ne peut fonctionner avec votre version de PRISM"
 exit
endif

False=0
true=1

REM ---------------------------------------------
rem Parametres utilisateur
rem ---------------------------------------------
rem Ce sont generalement les memes nuit apres nuit

Rem deplacement du télescope entre chaque champ en radian.
deplacementAlpha= 0.5235988
Deplacementdelta= 0.23

rem temps de pose pour la calibration
TempsdePosecali=5000

rem Nom du catalogue utiliser pour les mesures
// Catalog that can be used
Cat[1]$="GSC"
Cat[2]$="USNO SA"
Cat[3]$="USNO A1"
Cat[4]$="USNO A2"
Cat[5]$="Hipparcos"
Cat[6]$="SAO"
Cat[7]$="BSC"
Cat[8]$="Tycho1"
Cat[9]$="GSC-ACT"
Cat[10]$="Tycho2"
Cat[11]$="UCAC1/2"

Catalog$=Cat[9]$

rem Chemin du catalogue pour une recalibration du télescope
rem sDirCatalogue$="C:\Catalogues\USNO A2\"
sDirCatalogue$="C:\Astronomie\Catalogues\Gsc-Act\"
rem sDirCatalogue$="C:\Catalogues\UCAC2\u2\"

rem  Image orienté Nord SUD?
NSo=TRUE

rem Nombre d'etoile de comparaison utiliser dans le catalogue
NbStarCat=150

rem Nombre d'etoile de comparaison utiliser dans l'image
NbStarImg=150

Rem degre du polinome de correction de la deformation de l'image
DegPoly=2

Rem Delai avant debut de la pose
DelayBeforeExposure=10000

Rem reglage du binning pour les images
nBinning=3

Rem Elevation minimum d'observation des objets
ElevationMinDeg = 20.0

Rem delta maxi des objets
DeltaMaxDeg = 80

rem ---------------------------------------------
rem Debut du programme general
rem ---------------------------------------------

rem GET_TELESCOPE_POSITION Alpha Delta Hauteur Azimuth AngleHor

nbMesure=0

SetBinningX nBinning
SetBinningY nBinning

DrapeauAntiNord=true

for nDelta=-2 to 4
 for nAlpha=-1 to 5
 
 GetStdrLatitude Delta
 GetStdrLongitude Lon
 now date
 SideralTime date Lon Alpha
 
 AlphaPoint=Alpha-((nAlpha-2)*deplacementAlpha)
  if AlphaPoint>(2*PI)
   AlphaPoint=AlphaPoint-(2*PI)
  else 
   if alphaPoint<0
    AlphaPoint=(2*PI)+AlphaPoint
   endif
  endif
  
  DeltaPoint=Delta-(nDelta*Deplacementdelta)
  
  Now Date
  GetStdrLongitude Lon
  GetStdrLatitude Lat
  ElevationMin =ElevationMinDeg*TORAD
  GetHeight AlphaPoint deltaPoint date Lon Lat ObjectElevation
  If (ObjectElevation<ElevationMin) then
   print "Champ impossible Hauteur: " AlphaPoint "  " deltaPoint
   goto ChampSuivant:
  endif
  
  DeltaMax=DeltaMaxDeg*TORAD
  If (deltaPoint>DeltaMax) then
   print "Champ impossible Delta: " AlphaPoint "  " deltaPoint
   goto ChampSuivant:
  endif
  
  rem SHOWRADEC_SKYMAP AlphaPoint DeltaPoint
  rem print "Champ: " AlphaPoint "  " deltaPoint
  rem goto ChampSuivant:
  
  rem goto AntiNordHS:
  if (DrapeauAntiNord=true) then
   AlphaPoint2=Alpha
   if AlphaPoint2>(2*PI)
    AlphaPoint2=AlphaPoint2-(2*PI)
   else 
    if alphaPoint2<0
     AlphaPoint2=(2*PI)+AlphaPoint2
    endif
   endif
   MoveTelescope AlphaPoint2 deltaPoint
   WaitForEndMoveTelescope
   DrapeauAntiNord=false
  endif
  AntiNordHS: 
  
  MoveTelescope AlphaPoint deltaPoint
  SHOWRADEC_SKYMAP AlphaPoint DeltaPoint
  WaitForEndMoveTelescope

  Delay DelayBeforeExposure
  WaitForEndDelay
  
  StartExposure TempsdePosecali
  Delay TempsdePosecali/2
  WaitForEndDelay
  Now Date
  WaitForEndExposure
  GetLastImageExposure img
  
  
  rem GET_TELESCOPE_POSITION AlphaTheorique DeltaTheorique Hauteur Azimuth AngleHorTheorique
  GET_TELESCOPE_POSITION_APP AlphaTheorique DeltaTheorique
  
  getFocus img focus
  rem Print "Focale = " Focus
  if Focus=0
  Print "Remplir l'entete des images avec la focale de l'instrument."
  endif

  GetSizePixX Img TaillePixX
  rem Print "Taille Pixel X = " TaillePixX
  GetSizePixY Img TaillePixY
  rem Print "Taille Pixel Y = " TaillePixY
  if TaillePixX=0
   Print "Remplir l'entete des images avec la taille des Pixels."
  endif
  if TaillePixY=0
   Print "Remplir l'entete des images avec la taille des Pixels."
  endif
	  
  GetBinX Img BinX 
  rem Print "Binning X = " BinX
  GetBinY Img BinY
  rem Print "Binning Y = " BinY
  if BinX=0
   Print "Remplir l'entete des images avec le Binning des Pixels."
  endif
  if BinY=0
   Print "Remplir l'entete des images avec le Binning des Pixels."
  endif
	  
  GetAlpha Img AD
  rem Print "Alpha = " AD
  GetDelta Img DC
  rem Print "Delta = " DC
  if AD=0
   Print "Remplir l'entete des images avec la position centrale du champ"
  endif
  if DC=0
   Print "Remplir l'entete des images avec la position centrale du champ"
  endif
	
  EtalonAstrometrieAuto Img Catalog$ Focus TaillePixX*BinX TaillePixY*BinY AD DC NbStarCat NbStarImg NSo DegPoly sDirCatalogue$ Valid
	
  if Valid=1
   Width img width
   round width/2 widthDiv2
   Height img height
   round height/2 heightDiv2
   GETIMG_XY_TO_RADDEC img widthDiv2 heightDiv2 Alpha2000 Delta2000
   CONVERT_RADEC2000_TO_APP Date Alpha2000 Delta2000 AlphaCenter DeltaCenter
   
   rem GETDATE Img Date
   GetStdrLongitude Lon
   GetStdrLatitude Lat
   GetHeight alphaCenter deltaCenter date Lon Lat ObjectElevation
   SideralTime date Lon TSL
   ComputeAngleHor TSL alphaCenter AngleHorVrai
   ComputeAngleHor TSL AlphaTheorique AngleHorTheorique
   str nbMesure nbMesure$
   str AngleHorTheorique AngleHorTheorique$
   str DeltaTheorique DeltaTheorique$
   str AngleHorVrai AngleHorVrai$
   str DeltaCenter DeltaCenter$
   print nbMesure$ "  " AngleHorVrai$ "  " DeltaCenter$ "  " AngleHorTheorique$ "  " DeltaTheorique$
   nbMesure=nbMesure+1
  else
   Print "Calibration echouée... pas de mesure sur le champ"
  endif
	
  Close img
ChampSuivant:
 next nAlpha
 DrapeauAntiNord=true
next nDelta

Print "Liste de modele de pointage réalisée!"