Modele monture HPS 10 micron

[Jean-Louis Tressol]

Bonjour,

Y a t il sous prism v9 un moyen de créer un modèle de pointage en automatique pour une monture HPS 10 micron dans le même esprit qu'avec le soft Model Maker de Per Frejvall? Pour mémoire ce dernier pointe automatiquement une série de champs choisis par l'utilisateur, prend un cliché, fait la résolution astrométrique via MaximDl + pinpoint et injecte directement les coordonnées dans le micrologiciel de la monture.Pour le pilotage monture et caméras ça marche très bien et j'aimerais bien pouvoir tout faire avec Prism, y compris l'alignement initial sur trois étoiles, la mise en station et le modèle.

Merci

[Gielen_Frederic]

Bonjour, il y a possibilité de faire un modèle de pointage en automatique avec Prism, c'est dans l'onglet " Télescope/Observatoire ->pointer des champs... puis calcul du modèle de pointages.

Dans le même onglet, il y a la mise en station par la méthode de King.

Tu as quelle monture 10 Micron?Je possède la 2000 HPS.

FredGie

[Jean-Louis Tressol]

Bonjour Frederic et merci pour ta reponse. J'ai la 1000HPS. J'avais bien vu la fonction pointage de champ puis calcul du modèle mais je ne vois pas ou est la connexion avec le firmware de la monture. Parmi les nouveautès de la V9 il y a "l'optimisation du modèle de pointage pour les montures GM 10 micron". Sais tu de quoi il s'agit?

JL

[Gielen_Frederic]

Pour l'amélioration du modèle de pointage il faut voir avec Ciryl , tu effectues un modèle pour le tube à l'Est puis un modèle tube a l'Ouest pour une monture équatoriale , les calculs te donnent 2 fichiers qu'il faut déclarer dans la config du télescope. Je suppose que c'est prism qui corrige les données, puis il transmet les données de pointages corrigées à la monture.
FredGie

[Jean-Louis Tressol]

OK, merci. Peut-être que si Cyril passe par là il pourra nous en dire plus. Je comptais aussi aborder le sujet avec Stéphane Charbonnel fin Juillet á l'OHP mais je me suis inscrit trop tard et il n'y avait plus de place...

[Cyril Cavadore]

c'est un modele de pointage de type tpoint et corrige les coordonnées a pointer, il faut faire un modele coté ouest et est de la monture.
Si tu vois Stephane, ca va bien se passer.

[Jean-Louis Tressol]

Merci Cyril. J'espérais voir Stéphane a l'OHP fin Juillet mais c'est raté, j'essaye de le joindre pour en parler.

[Stéphane Charbonnel]

Bonsoir,

D'abord je tiens à préciser que rien ne vaut d'utiliser le modèle de pointage intégré et calculé par le calculateur de la monture elle-même. Attention, je ne dis pas que le modèle de pointage créé par PRiSM n'est pas bon, loin de là et d'ailleurs il marche très bien pour la NOVA. Mais que ce soit pour le GEMINI, APCC l'arlésienne d'AP et la 10µ, il est toujours bon d'utiliser le modèle intégré.
Voici la procédure quasi nomade que j'ai mise en place l'été dernier :
1) Alignement manuel de la monture le mieux possible (toujours mieux que de commencer à 5°)

2) Mise en station plus ou moins grossière :
Ceci se fait à l'aide de la raquette de la monture. Il n'est donc pas obligatoire de connecter la monture à PRiSM à ce moment là.
Avant tout, ne pas oublier d'effacer le modèle précédent : Menu > Alignment > Clear Align
Ensuite, une première mise en station grossière est réalisée à l'aide du menu Menu > Alignment > 3-stars : La raquette demande de pointer 3 étoiles par leur "foutu" nom (voir les 4 pages de la notice donnant la localisation des étoiles en fonction de leur nom). Un soir de début d'été, n'étant pas très fort dans la mémorisation des noms propres d'étoiles je choisis par exemple Déneb - Véga et Alkaïd (Grande Ourse), la dernière étoile étant forcément de l'autre côté du méridien par rapport aux deux autres. Ce système permet, dixit le manuel, de déterminer l'erreur de mise en station ainsi que d'estimer le défaut d'orthogonalité entre l'axe optique et l'axe delta. Evidemment, le nombre d'étoile de choix se restreint au fur et à mesure des pointages et le dernier est forcément de l'autre côté.
Une fois chacune des étoiles recentrées bien au centre du capteur CCD (en prenant soin de cocher auparavant sous PRiSM : grille sur l'image), il suffit d'aller directement dans Menu > Alignment > Polar Align afin de pointer une étoile (toujours par son foutu nom !). L'étoile va forcément passer à côté du centre du capteur et atterir peut être bien loin ! Le jeu consiste à l'aide des réglages altitude et azimuth de recentrer l'étoile au centre du capteur. Au début c'est assez déroutant car on a l'impression que sur certains objets visés, l'action des deux boutons est plutôt similaire (et non perpendiculaire comme on pourrait l'imaginer au départ) mais à bien y regarder, on arrive toujours à rencentrer l'objet dans le capteur. Pour que ce soit le plus le cas, choisir aux environs de DEC=00° et 50° du méridien SUD soit ici dans le même exemple Altair (et non Deneb comme choisi au départ)
Une fois cette opération effectuée, on a une première mise en station que je qualifierai de limite. Le choix des étoiles y fait surement mais la raquette supprime des choix d'étoiles au fur et à mesure afin d'imposer une certaine distance entre les protagonistes.
Pour une mise en station plus fine, je recommence l'opération une deuxième fois : c'est cinq minutes de perdues mais un affinage certain.

Ensuite, preuve que l'alignement est suffisant : j'efface le modèle précédent : Menu > Alignment > Clear Align et je recommence un alignement sur 4 étoiles (sans toucher aux boutons azimuth et altitude).
J'obtiens un truc dnas le genre :
Aligned with 4 stars
Az 000°00'30"
Alt 47°02'51"
Polar align err : 000°00'55"
PA 338°10'
Scope ortho err. : 00°02'27"
Model terms : 3
Exp.RMS : 29.6"
Align stars : Dened, Vega, Alkaid, Altair

3) Modèle de pointage :
Rien n'est effacé dans la base de donnée initiale : je garde mes 4 étoiles d'alignement 3-stars + 1 refine-star.
Tous les pointages et reconnaissances sont effectués avec PRiSM v9.
1. Configuration du télescope : Connecter en J2000 via le driver ASCOM de Per Frejvall. Choisir "Sync Refine" mais ne pas faire de calibration.
2. Configuration de la caméra.

Je me définis un fichier LST de champ à pointer à l'aide du menu "Telescope / Pointer des champs pour modèle de pointage". Je ne lance rien depuis ce menu mais je crée juste le fichier LST. Attention par expérience de ne pas aller des champs > à DEC=75°.
Je me suis fait à ce moment là un petit script pour pointer ces champs au fur et à mesure et calibrer depuis le centre du champ.
La fonction central du script est FIND_ALLSKY_POSITION soit l'équivalent de la fonction retrouver position du télescope : donne les coordonnées du centre de l'image et calibre à partir de ces coordonnées. La monture a donc pour le champ les coordonnées de pointage là où elle "pense" avoir pointé et les coordonnées apparentes, là où elle a réellement pointé.
Le script est le suivant :

Code : Tout sélectionner

// REM T300 et modèle de pointage 10µ 2000HPS
Camera=1
Pose=15000
Bin=2
AngleCCDChampWEST=0.64
AngleCCDChampEAST=180.64
DirRep=0
NomFichier$="C:\Partage\T300 MP\Liste_MP.lst"

STR Camera Camera$
STR Pose Pose$
STR Bin Bin$
Niveau1LST$=""""
Niveau2LST$=" "


NumChamp=1
FileExists NomFichier$ ResultatTest
If ResultatTest=1 then
  OPEN_FILETXT_FOR_READ f1 NomFichier$
  READFILETXT f1 ligne$
  CUTSTR ligne$ Niveau1LST$ 2 ligne$
  CUTSTR ligne$ Niveau2LST$ 1 rad$ 
  RA_TO_RAD Rad$ alphaC[NumChamp]
  CUTSTR ligne$ Niveau2LST$ 2 Dec$
  DEC_TO_RAD Dec$ deltaC[NumChamp]
  // PRINT RAD$ " " alphaC[NumChamp]
  // PRINT DEC$ " " deltaC[NumChamp]

  EtoileEtalonSuivante:
  ENDOFFILE f1 eof
  If eof<>1 then
   NumChamp=NumChamp+1
   READFILETXT f1 ligne$
   CUTSTR ligne$ Niveau1LST$ 2 ligne$
   CUTSTR ligne$ Niveau2LST$ 1 Rad$
   RA_TO_RAD Rad$ alphaC[NumChamp]
   CUTSTR ligne$ Niveau2LST$ 2 Dec$
   DEC_TO_RAD Dec$ deltaC[NumChamp]
   // PRINT RAD$ " " alphaC[NumChamp]
   // PRINT DEC$ " " deltaC[NumChamp]
   goto EtoileEtalonSuivante:
  else
   if NumChamp=1 then
    print "Qu'une seule étoile de référence!"
    exit
   endif
  endif
  CloseFileTxt f1
else
  print " Fichier inexistant!"
  exit
Endif

NbChamp=NumChamp
For NumChamp=1 NbChamp
   AlphaDest=AlphaC[NumChamp]
   DeltaDest=DeltaC[NumChamp]
   GOSUB Pointage: 
   PIERSIDE_TEL ActualSide$
   Temp=Pose/1000
   STR Temp Pose$
   Chaine$="Camera n°"+Camera$+"; binning ="+Bin$+"; Pose de "+Pose$+"sec"
   PRINT Chaine$
   PIERSIDE_TEL ActualSide$
   if ActualSide$="WEST" then
     SetCCDOriCamHeader Camera  AngleCCDChampWEST
   else
     SetCCDOriCamHeader Camera  AngleCCDChampEAST
   EndIf
   SetCCDRepDirCamHeader Camera DirRep
   SETBINNINGX_EX Camera Bin
   SETBINNINGY_EX Camera Bin
   STARTEXPOSURE_EX Camera Pose
   WAITFORENDEXPOSURE_EX Camera
   GETLASTIMAGEEXPOSURE_EX Camera ImgChamp
   MaxStarImg=80
   MaxStarCat=80
   Field=1
   Cat$="GSC-ACT"
   FIND_ALLSKY_POSITION ImgChamp MaxStarImg MaxStarCat Field Cat$ Valid
   If Valid=1 then
      PRINT "Reconnaissance réussie"
	  PRINT " "
   Else
      PRINT "Reconnaissance échouée"
	  PRINT " "
   EndIf
   Close ImgChamp
Next NumChamp

END   
   
Pointage:
  MoveTelescope AlphaDest DeltaDest
  RAD_TO_RA AlphaDest AlphaDest$
  RAD_TO_DEC DeltaDest DeltaDest$
  Chaine$="Pointe vers "+AlphaDest$+"  "+DeltaDest$
  PRINT Chaine$
  WaitForEndMoveTelescope
RETURN

Ensuite, le modèle de pointage doit être bon.
Déconnecter le driver ASCOM et se reconnecter en "Sync align".

Stéphane

[Jean-Louis Tressol]

Bonjour Stéphane,

Merci pour la procédure détaillée et pour le script, c'est l'occasion de s'y mettre

Jean-Louis

[Cyril Cavadore]

je vais mettre la reponse de stephane dans un PDF