commande StopGuide

[Richard Villeminot]

Bonjour,

Je démarre manuellement l'autoguidage avec ma ST402 puis je lance un script avec la commande StopGuide, les boutons "autoguidage" et "calibration" redeviennent actif, le bouton "abandon" est désactivé mais l'autoguidage se poursuit!... et la commande "Close_CCD_Camera" plante.

Merci
Richard

[Cyril Cavadore]

Quelle version SVP ?
Merci

[Richard Villeminot]

Version 7.2.01 en démo
Richard

[Cyril Cavadore]

Il faut demarrer un script avec la commande qui démarre le guidage et terminer avec la commande script stopguide.
Les actions entrelacés script, et interface utilisateur sont interdites.
J'ai mis un message d'erreur si tu fais un stopguidage sans avoir fait de commande startguide ton script d'arretera avec une erreur...
Applicable sur 7.2.7
Cyril

PS : modif de la fonction startguide :
TRUE=1
FALSE=0

// STARTGUIDE
//
// CCDNum : Numero de ccd de guidage 0=principal 1=CCD auxiliaire
// ExpTime : Temp de pose en sec
// WindowSize : Demi Taille de la fenetre de guidage (pixels)
// CentroSize : Demi Taille pour le centroide (pixels)
// StarThresADU : Seuil de l'toile, si pas d'etoile au dessus du seuil, = erreur pas de guidage
// AgressRA : Agressivite RA (0 à 2)
// AgressDelta : Agressivite DEC (0 à 2)
// RaMin : Nbre de pixels Min de deplacement en RA (Pixels)
// RaMax : Nbre de pixels Max de deplacement en RA (Pixels)
// DecMin : Nbre de pixels Min de deplacement en DEC (Pixels)
// DecMax : Nbre de pixels Max de deplacement en DEC (Pixels)
// CurrentDEC : Delta courant (ignoré si codeurs sont actifs et/ou telescope actifs)
// AlarmEnabled : 0 = Pas d'alarmes 1 = Alarmes
// DeltaMoveFashion: 0 = Normal, 1 pas de mvt delta, 2 Mvt positifs seulement, 3 Mvt Negatifs seulements
// Valid : 0 = OK 1 = deja en train de guider 2=Erreur d'init
// message$ : vide si pas d'erreur
// Cette fonction rends la main qd le guidage est bien etabli, en boucle (ou sur une erreur!)


// La calibration devra etre realisee en mode non-script prealablement, le guidage est realisé selon cette calibration
// qui est lue depuis la base de registres
// Si la calibration n'est pas realisee, cela va renvoyer une erreur et stopper le script

// STARTGUIDE Choisi automatiquement l'etoile, la plus brillante du champ, au dessus de "StarThresADU"
// Si l'etoile guide n'est pas trouvée
// - soit elle trop faible
// - soit PRISM n'arrive pas a en faire le centroide evolué (pour eliminer tout risque de guidage sur des pts chauds)
// (NB:ce qui veut dire que certainement ca risque d'ejecter des etoiles qui sont tres deformees par la coma ?)
//
// Dans la suite, utiliser GET_GUIDE_STATUS CCDNum Status LastErrorMessage$ permet de savoir si le guidage est bien en place :
// Status passe a 0 (pas de guidage) et LastErrorMessage$ renvoie le message comme quoi l'etoile guide n'est pas trouvee
// Ceci dans le but de ne pas provoquer d'erreur fatale au script et provoquer son arret.


MainCCD=1
TrackingCCD=2

StatusGuideRunning=1
StatusGuideIdle=0



CCDNum=MainCCD

Exptime=0.05

WindowSize=30
CentroSize=5
StarThresADU=10

AgressRA=0.4
AgressDelta=0.7

RaMin=0.01
RaMax=3

DecMin=0.01
DecMax=3

CurrentDEC=0

AlarmEnabled=TRUE
DeltaMoveFashion=0

NbPoses=10
ExpoMsMain=60*1000


na$="c:\temp\testG-"
ext$=".cpa"

Print "Demarrage du guidage"

STARTGUIDE CCDNum ExpTime WindowSize CentroSize StarThresADU AgressRA AgressDelta RaMin RaMax DecMin DecMax CurrentDEC AlarmEnabled DeltaMoveFashion Valid message$

Print "StartGuide Status = " Valid


If Valid=0 then

Print "Guidage démarré !"

For i=1 NbPoses

// Guidage en cours ?
GET_GUIDE_STATUS CCDNum Status LastErrorMessage$

If Status=StatusGuideRunning
Print "Status de guidage : Guidage en cours, Dernier Message=[" LastErrorMessage$ "]"

Print "Demarre la pose sur le grand CCD"
STARTEXPOSURE ExpoMsMain

WAITFORENDEXPOSURE

Print "Fin de la pose sur le grand CCD"
str i i$

GETLASTIMAGEEXPOSURE Img
Autovisu Img
saveCPA Img na$+i$+ext$
Close Img


Print "Pose n°" i$ " terminee !"


endif

If Status=StatusGuideIdle
Print "Status de guidage : Guidage inactif, Dernier Message=[" LastErrorMessage$ "]"
Delay 10000
WaitforEndDelay
endif


next i

// Arret du guidage
STOPGUIDE CCDNum
Print "Guidage terminé"


else
Print "Erreur de demarrage de guidage = " Valid " Cause= " message$
endif