Script d'acquisition d'images pour mesures de tilt et courbure et réduction 4 côtés.

L'utilisation et la création des scripts.
Répondre
Alain-Maury
Messages : 94
Enregistré le : 19 juin 2009, 04:14

Script d'acquisition d'images pour mesures de tilt et courbure et réduction 4 côtés.

Message par Alain-Maury »

Bonjour,
Lorsque l'on règle un télescope, et ce d'autant plus que le détecteur est grand, on doit réaliser une série d'images, passant à travers le foyer correct, de façon à calculer le tilt et la courbure de champ avec la fonction de prism qui fait ça.
J'ai depuis pas mal de temps un script qui permet de réaliser ça. Il crée, en même temps, des images réduites aux 4 coins (plus centre). Ces images en jpg permettent de visualiser déjà assez rapidement ce qui se passe au niveau du champ, voir si toutes les images ont la bonne mise au point à la même valeur de focalisation.

A copier dans notepad++ et sauvegarder en testfocus.pgm ( ou tout autre nom de votre choix).

REM Script taking a series of focus images, and saving them.
REM Alain Maury - Version de Aout 2020
REM On considère que la caméra, focuser et télescope sont déjà connectés dans prism


resetdlgbox
adddlgbox 1 1000 0 "Start focus value: " 0
AddDlgBox 1 1000 0 "End focus value: " 0
AddDlgBox 1 1000 0 "Focus step: " 0
adddlgbox 2 30 1 "Exposure time (seconds): " 5
adddlgbox 2 10000 10 "Subwindow size (pixels): " 400


dispdlgbox result
GetDlgBox focusmin
getdlgbox focusmax
getdlgbox focusstep
getdlgbox exptime
getdlgbox subwindow

REM First we enter the values of focus
print "Minimum focus value : " focusmin " mm"
print "Maximum focus value : " focusmax " mm"
print "Focusing step : " focusstep " mm"
print "Exposure time : " exptime " seconds"
print "Size of the subwindow : " subwindow " pixels"
expotime=exptime*1000
numberoffocusimages=(focusmax-focusmin)/focusstep
int numberoffocusimages numberoffocusimages
print "The number of exposure will be :" numberoffocusimages
print "Now choosing the directory where to store the images"
getrepname directory$
print "directory is : " directory$

for i=0 numberoffocusimages
focusvalue=focusmin+(i*focusstep)
print "focus value : " focusvalue
set_focuser focusvalue
REM on attend 3 secondes
delay 3000
waitforenddelay
startExposure expotime
waitForEndExposure
REM Recovering the image in order to save it
getLastImageExposure img
print "Exposure finished"
strf focusvalue 2 focusvalue$
Nameimage$="focustest_"+focusvalue$
print "Image's name : " Nameimage$
savecpa img directory$+Nameimage$
REDUC_COLL img subwindow
savejpg img directory$+"4corners"+Nameimage$
close img
next i
end
Répondre