Utilisation du Sony A7s sous prism

Tout ce qui concerne la gestion des instruments dans PRiSM.
L'observation automatique est incluse dans ce forum.
Répondre
Alain-Maury
Messages : 94
Enregistré le : 19 juin 2009, 04:14

Utilisation du Sony A7s sous prism

Message par Alain-Maury »

Bonjour,
Normalement j'aurai du passer ça dans la rubrique des scripts, mais ça concerne aussi l'utilisation du Sony A7s. C'est à mon avis d'assez loin le boitier reflex le plus sensible pour l'astronomie, sauf que le soft de la caméra est plutôt nul. La prise en main pour un "Canon-iste" est aussi un peu compliquée. Sony ne donne aucune information sur la gestion de la caméra (pas de sdk, software developement kit), et Cyril, comme les autres programmeurs d'ailleurs, n'ont pu faire quoique ce soit pour commander la caméra en remote. J'en ai acheté un l'année dernière, que Richard Galli ( http://www.eosforastro.com/ ) m'a défiltré. Ce boitier est une tuerie, genre avec un 24mm F/1.4 faire une pose de 1 seconde sur la voie lactée à main levée et sortir une image très belle. Mais difficile, une fois derrière un télescope, de faire la mise au point. La visée sur l'écran n'est pas assez précise. On peut utiliser un masque de Bahtinov, mais si on n'en a pas, on utilise prism, que tout le monde ici utilise :).
Il existe une application de Sony pour contrôler le boitier en remote via un câble USB. De là, j'ai écrit un script sous prism pour la focalisation.
L'idée est la suivante : on lance l'appli Sony, on fait une image, on note le dossier dans lequel on stocke les images (normalement avec le numéro de la nuit, etc...). Au lancement du script, on va chercher la dernière image prise par le boitier, histoire d'avoir le directory et le numéro de la dernière image (genre DSC01458.ARW). De là, prism regarde toutes les secondes s'il existe une nouvelle image (donc DSCO1459.ARW), si non, ça continue en boucle, mais dès qu'une image est prise, prism l'ouvre (la sépare en trois plans, ne garde que le plan vert), demande de sélectionner une étoile sur laquelle on va mesurer la taille de l'image (ça se fait via un getpoint img x y). Et à partir de cette image, va sortir une image de 200x200 pixels (on peut modifier le script pour que ça soit plus grand ou plus petit), qu'il va zoomer 3x (là aussi on peut faire plus ou moins), demander, via un getpoint de centrer l'image, et calculer sa largeur à mi hauteur, et l'afficher sur l'image.
A l'image suivante, il n'affiche que l'image de 200x200, mesure à la même position la largeur de l'étoile, sauf s'il ne la trouve pas auquel cas il redemande de la centrer.
Ca permet donc de prendre des images, de voir la taille des étoiles, de changer le focus (via prism, ou via l'application commandant le focuser, ou à la main en bougeant la molette du focuser), reprendre des images, etc... Quand on pense qu'on est bon, on arrête le script à la main.
Pas l'idéal, par exemple sous prism avec un boitier canon on peut vraiment le gérer comme une caméra CCD, faire une focalisation automatique, mais au moins ça permet de faire la mise au point.
Le forum de prism ne permettant pas de joindre des fichiers .pgm ou .txt (bizarre, Cyril ???), si vous êtes intéressés, veuillez me le demander en email perso a amaury chez spaceobs point com
Alain
Cyril Cavadore
Messages : 4481
Enregistré le : 18 juin 2009, 22:41
Localisation : 42

Re: Utilisation du Sony A7s sous prism

Message par Cyril Cavadore »

Merci !
Si tu peux mettre le code sous la forme

Code : Tout sélectionner

Ici du code ...
Cyril Cavadore, ALCOR-SYSTEM, Auteur de PRISM
http://www.alcor-system.com

Pour reporter vos problème, la marche à suivre est ici
viewtopic.php?f=7&t=1403
Alain-Maury
Messages : 94
Enregistré le : 19 juin 2009, 04:14

Re: Utilisation du Sony A7s sous prism

Message par Alain-Maury »

Voici le script (j'avais pas vu l'option "code" ) :

Code : Tout sélectionner

REM Programme de focalisation du Sony A7s
REM Alain Maury - Mars 2017
REM Le programme demande tout d'abord de pointer sur la dernière image prise,
REM Récupère le nom du directory et le numero de l'image.
REM Ensuite il regarde toutes les secondes s'il y a une nouvelle image
REM S'il y a une nouvelle image, il l'ouvre, la convertit en image couleur,
REM Et demande de cliquer sur une étoile et donne sa largeur à mi hauteur (FWHM)
REM Ensuite il retourne dans la boucle et dès qu'il y a une nouvelle image
REM l'affiche et mesure la largeur de l'étoile. S'il n'y a pas d'étoile
REM Il redemande un pointage. S'il n'y a pas d'étoile, il sort du programme
REM on déclenche l'image avec l'application de Sony, mais on peut mesurer la qualité d'image avec prism.
REM constantes
Dem_Larg=11
windowsize=100
zoom=3
image=0
// $02FFFFFF ou $02RRGGBB en hexa, ce qui donne en decimal :
WHITECOLOR=50331647
writex=10
writey=10
Taille=25
colortext=WHITECOLOR
ColorBackGND=0
FontName$="Arial"
nouvelleimage=1


REM On pointe sur la dernière image
Print "Ouvrez la derniere image prise"
GetFileName lastimage$
ExtractFileName lastimage$ nomlastimage$
ExtractFilePath lastimage$ directory$
REM On vire la partie DSC0 du nom de l'image et on convertit en nombre
SUBSTRING nomlastimage$ 5 4 Number$
VAL Number$ Number


REM On regarde dans le directory pour l'image suivante
checkfile:
INCR Number
if Number<10 then
	nomimage$="DSC0000"
else
	if Number<100 then
	nomimage$="DSC000"
	else
		if Number<1000 then
			nomimage$="DSC00"
		else
			if Number<10000 then
				nomimage$="DSC0"
			endif
		endif
	endif
endif

str Number Number$
nextimage$=directory$+nomimage$+Number$+".ARW"
getcenter:
FILEEXISTS nextimage$ YesNo
if YesNo=1 then 
REM Il y a une nouvelle image, on l'ouvre, on la convertit et on garde l'image verte
	nouvelleimage=1
	open img nextimage$
	splitbayerimg img 2 imgR imgV imgB
	close img
	close imgR
	close imgB
	BinningReduce  ImgV 1 2
	autovisu imgV
	if image=0 then
		getpoint imgV XL YL
	endif
	REM On fenêtre et on zoome l'image
	window imgV XL-windowsize YL-windowsize XL+windowsize-1 YL+windowsize-1
	scale imgV zoom PIXEL
	if image=0 then
		getpoint imgV X Y
	endif
	centroidGauss ImgV X Y Dem_Larg PosX PosY SigW SigH Angle Flux OMC HOMC ErrFlux
	if PosX=-1 then
		getpoint imgV X Y
		centroidGauss ImgV X Y Dem_Larg PosX PosY SigW SigH Angle Flux OMC HOMC ErrFlux
	endif
	REM On affiche l'image autour de l'étoile sélectionnée en plus grand
	strf sigW 2 sigW$
	strf sigH 2 sigH$
	REM on garde une copie sur l'écran du script
	print "Image " "DSC0" Number$ " FWHMX = " sigH " FWHMY = " sigW
	Text$="FWHMX = "+sigH$+" FWHMY = "+sigW$
	autovisu imgV
	REM On écrit sur le bas de l'image
	WRITETEXT ImgV writex writey Taille Text$ colortext ColorBackGND FontName$
	incr image
	REM close imgV
else
REM S'il n'y a pas d'images, on attend une seconde et on retente :)
	delay 1000
	waitforenddelay
	if nouvelleimage=1 then
		print "waiting for new image"
		nouvelleimage=0
	endif
	goto getcenter:
endif
goto checkfile:

Jean-paul GODARD
Messages : 105
Enregistré le : 22 sept. 2010, 17:44

Re: Utilisation du Sony A7s sous prism

Message par Jean-paul GODARD »

Ne perdons pas espoir...

Sony Electronics Announces New Camera Software Development Kit (SDK) for Third Party Developers and Integrators
New SDK Enables Remote Control of Sony Cameras for a Variety of Professional and Commercial Application
SAN DIEGO – Feb 11, 2020 –
Jean-Paul GODARD
Associations AT60 , OATBL , Uranoscope, Planète-Sciences TJMS
Patrice Le Guen
Messages : 281
Enregistré le : 19 janv. 2014, 18:06
Localisation : Toulon
Contact :

Re: Utilisation du Sony A7s sous prism

Message par Patrice Le Guen »

Bonjour,

Le lien vers le SDK (sources, dll, exemple) du pilotage en remote du SONY ALPHA 7 me semble maintenant disponible ici depuis peu :
https://support.d-imaging.sony.co.jp/ap ... index.html
Cyril Cavadore
Messages : 4481
Enregistré le : 18 juin 2009, 22:41
Localisation : 42

Re: Utilisation du Sony A7s sous prism

Message par Cyril Cavadore »

Oui, mais je n'ai pas d'APN de ce type sous la main ....
Cyril Cavadore, ALCOR-SYSTEM, Auteur de PRISM
http://www.alcor-system.com

Pour reporter vos problème, la marche à suivre est ici
viewtopic.php?f=7&t=1403
Répondre